*label stats_page
${name}
*line_break
$!{god} of Spring
*line_break
*line_break
[b]Traits[/b]
*line_break
*line_break
*if (tag_learned)
	[i]Learned[/i] - You're adept in matters academic, with a reliable memory and an analytical intellect.
	*line_break
	*line_break
*if (tag_athletic)
	[i]Athletic[/i] - You're physically fit and capable, picking up new kinetic skills with unusual aplomb.
	*line_break
	*line_break
*if (tag_magic)
	[i]Magically-Gifted[/i] - You have a natural knack for the magic of your domains, and an unusually-large reservoir of energy to work from.
	*line_break
	*line_break
*if (tag_intuitive)
	[i]Intuitive[/i] - You're observant and canny, able to pick up on subtleties both environmental and behavioral.
	*line_break
	*line_break
*if (tag_charming)
	[i]Charming[/i] - You've got a silver tongue, and a certain way with people. 
	*line_break
	*line_break
*if (tag_unlearned)
	[i]Brain Fog[/i] - You have trouble processing large amounts of information at once, especially if it's abstract or theoretical. But you know how to persevere, because you've had to.
	*line_break
	*line_break
*if (tag_unathletic)
	[i]Feeble[/i] - You're quite clumsy, and weaker than other demigods, tending to struggle in physically-demanding situations. But you've developed flexibility and techniques for minimizing injuries.
	*line_break
	*line_break
*if (tag_unmagic)
	[i]Magically-Impaired[/i] - Your reservoir of magic is small, and grand feats of magic will always be beyond you. But your control of magical energy is fine-tuned and precise.
	*line_break
	*line_break
*if (tag_unintuitive)
	[i]Oblivious[/i] - You're not very good at reading social cues or noticing what's going on around you. But your imagination is vivid, and you can spin a very good story.
	*line_break
	*line_break
*if (tag_uncharming)
	[i]Blank-Faced[/i] - Your resting expression and straightforward demeanor do not win you many friends, but you are very good at hiding things or keeping secrets when you need to.

*choice
	#Settings
		*if (erebus = 1)
			Erebus is currently ON.
		*if (erebus = 0)
			Erebus is currently OFF.
		
		*if (npc_init)
			NPC Initiative is currently ON.
		*if (npc_init = false)
			NPC Initiative is currently OFF.
		
		*if (convotoggle)
			Tone indicators are currently ON.
		*if (convotoggle = false)
			Tone indicators are currently OFF.
		
		*if (touchtoggle = "default")
			Touch settings are currently DEFAULT.
		*if (touchtoggle = "allaverse")
			Your touch setting is currently ALL AVERSE.
		*if (touchtoggle = "allallowed")
			Your touch setting is currently ALL ALLOWED.
		*if (touchtoggle = "allask")
			Your touch setting is currently ALL ASK.
		*if (touchtoggle = "individual")
			Your touch setting is currently INDIVIDUAL.
		
		What settings would you like to adjust?
		
		*fake_choice
			*if (pronouns_known)
				#I would like to use different pronouns.
					*goto pronoun_swap
			*if (erebus_known)
				#I would like to toggle Erebus's functionality. 
					*goto erebus_toggle
			#I would like to toggle NPC Inititative
				*goto init_toggle
			#I want to toggle tone indicators.
				*goto indicator_toggle
			#I want to see touch and touch aversion options.
				*goto touchtoggles
	#How to Play
		*goto howtoplay

*label pronoun_swap

What pronouns do you want to use?

*fake_choice
	#He/him.
		You are now using he/him pronouns, and will be titled accordingly.
		*set he "he"
		*set him "him"
		*set his "his"
		*set hes "he's"
		*set man "man"
		*set lord "lord"
		*set god "god"
		*set son "son"
		*goto stats_page
	#She/her.
		You are now using she/her pronouns, and will be referred to accordingly.
		*set he "she"
		*set him "her"
		*set his "her"
		*set hes "she's"
		*set man "woman"
		*set lord "lady"
		*set god "goddess"
		*set son "daughter"
		*goto stats_page
	#They/them.
		You are now using they/them pronouns, and will be addressed accordingly.
		*set he "they"
		*set him "them"
		*set his "their"
		*set hes "they're"
		*set man "person"
		*set lord "liege"
		*set god "deity"
		*set son "child"
		*goto stats_page
	#I would like to input my own pronouns.
		Of course! Please follow the prompts, so that you can be referred to correctly.
		*gosub_scene pronounscript
		*goto stats_page

*label erebus_toggle
Erebus, the system that provides data on the Underworld and navigation guidance, can be set not to provide you with any but emergency notifications, and to automatically decline all information requests sent to you. 

Otherwise, it will function as usual.

*fake_choice
	#I would like to toggle Erebus ON.
		*set erebus 1
		*goto stats_page
	#I would like to toggle Erebus OFF.
		*set erebus 0
		*goto stats_page

*label init_toggle
It is recommended that you set this variable at the beginning of your game and then leave it in place throughout. Continuity errors may occur if NPC Initiative is toggled throughout the game.

Would you like NPC Initiative to be toggled on? (See How To Play if you need an explanation for what this changes).

*fake_choice
	#Yes, set the NPC Initiative feature to ON.
		*set npc_init true
		*goto stats_page
	#No, turn the NPC Initiative feature OFF.
		*set npc_init false
		*goto stats_page

*label indicator_toggle
Tone indicators may be toggled on or off at any time without consequences to the story. If you find you need a little help interpreting the tone of some choice options, feel free to switch them on. Conversely, if you end up not needing them, they can be removed here.

For more information on how tone indicators work, see the 'Mechanics' section of 'How to Play,' accessible via the Stats Screen.

*fake_choice
	#I'd like to turn tone indicators ON.
		*set convotoggle true
		*goto stats_page
	#I'd like to turn tone indicators OFF.
		*set convotoggle false
		*goto stats_page

*label touchtoggles
Like [i]Asphodel[/i], [i]Blood of the Living[/i] allows you to play with varying levels of comfort towards touch. However, it is also meant to leave room open for characters to change their attitudes towards touch over time, either in general or from specific other people. 

Here, selecting 'DEFAULT' will preserve your settings from the last game (or from your last use of this menu, if you have previously used it), and periodically provide opportunities in the game to change how your character feels about touch with respect to specific characters. 

'ALWAYS AVERSE' will set your touch settings to averse for all characters, and the usual options to change how your character feels about it will not appear. 

'ALWAYS ALLOWED' will set your touch settings to indicate your character has informed everyone that they are generally fine being touched in casual ways. Some dialogues on the matter will still appear, e.g., in cases of non-casual or romantic touch, but for the most part, it will be assumed that the character is open to physical contact. 

'ALWAYS ASK' will set your touch settings such that all characters will seek permission to make physical contact, when the situation calls for it. The usual options to change how your character feels about it will not appear. 

'INDIVIDUAL' will allow you to choose your comfort level with each individual character. Doing so will set that option statically until you manually change it; opportunities to do so in the game will not appear. 

*fake_choice
	#Set touch to DEFAULT.
		*set touchchange true
		*set touchtoggle "default"
		*goto stats_page
	#Set touch to ALWAYS AVERSE.
		*set touchchange false
		*set hades_touch2 "averse"
		*set hermes_touch2 "averse"
		*set charon_touch2 "averse"
		*set pyri_touch2 "averse"
		*set alekto_touch2 "averse"
		*set hekate_touch2 "averse"
		*set touch2 "averse"
		*set touchtoggle "allaverse"
		*goto stats_page
	#Set touch to ALWAYS ALLOWED.
		*set touchchange false
		*set hades_touch2 "permission"
		*set hermes_touch2 "permission"
		*set charon_touch2 "permission"
		*set pyri_touch2 "permission"
		*set alekto_touch2 "permission"
		*set hekate_touch2 "permission"
		*set touch2 "permission"
		*set touchtoggle "allallowed"
		*goto stats_page
	#Set touch to ALWAYS ASK.
		*set touchchange false
		*set hades_touch2 "ask"
		*set hermes_touch2 "ask"
		*set charon_touch2 "ask"
		*set pyri_touch2 "ask"
		*set alekto_touch2 "ask"
		*set hekate_touch2 "ask"
		*set touch2 "ask"
		*set touchtoggle "allask"
		*goto stats_page
	#Set touch to INDIVIDUAL.
		*set touchchange false
		*set touchtoggle "individual"
		*gosub_scene touchscript
		*goto stats_page


*label howtoplay
Welcome to [i]Fields of Asphodel[/i]! 

If you're unfamiliar with Interactive Fiction (IF), the type of story this is, you may find the 'What is this game?' section helpful. If you're familiar with IF in general, but would like to learn more about [i]Asphodel's[/i] specific mechanics, the 'Mechanics' section is for you.

*fake_choice
	#What is this game?
		[i]Blood of the Living[/i] is an interactive fiction. Works of this style are characterized by the player's control over the narrative, usually in the form of making choices for one or more of that narrative's central characters. An IF often reads a lot like a traditional novel, except for the fact that the player makes choices for the Player Character (PC), and in so doing, affects how the story goes. 
		
		Many IFs also use numerical player statistics, such as strength or charisma, or personality statistics, such as humor or seriousness, to affect what happens in the story. If a player chooses to make their character consistently humorous, or to play a strong character, there are times when this may affect the story, such as another character commenting on the PC's sense of humor, or only being able to lift a heavy object if the PC is strong enough. 
		
		[i]Blood[/i] uses a version of these statistics, which are explained in more detail in the Mechanics section. But the basic idea is simply this: the kind of PC you choose to play, and the actions you choose for them to take in the story, will affect how the story goes. This is the central design principle of IF: your choices matter. Sometimes in big ways and sometimes in small ones, and always within the frame of the story itself—but much of how that story goes is up to you!
		
		Of course, there are plenty of Interactive Fictions out there, each with their own take on the format. This game itself is a sequel to a different game, called [i]Fields of Asphodel[/i]. Its specifics are explained a bit more in the 'Mechanics' section, but are also left for you to discover by playing the game itself. I encourage you not to worry too much about anything but playing your character and seeing how events unfold.
		*page_break
		*goto howtoplay
	#Mechanics
		Several of [i]Blood's[/i] mechanics are a little different from some other games in the IF format. A bit about that is explained in the below sections. That said, if you've played an IF before, you probably know enough to play this one without misunderstanding anything.
		
		*label mechmenu
		*fake_choice
			#How does romance work in this game?
				Romance works… more or less like it works in any game of the sort. You build a connection with an NPC, and if things go well, you end up in a relationship. Granted, the specifics are kind of important here, so here are some key things to note:
				
				1. You don't have to flirt with anyone to initiate romance. If you're using tone indicators, some options will be marked with a heart, indicating that they have anything from overt flirtatious intent to subtle or even subconscious romantic undertones. (If you aren't using indicators, they still do, but they won't be marked). Unlike in [i]Asphodel[/i], where you didn't need to choose any of these options to get onto a character's 'path,' In [i]Blood of the Living[/i], you are already on a path. At some point, you will need to indicate romantic interest to change that path from the platonic version to the romance, but these points should be very clear, so no PC is obliged to flirt in this game, either.
				
				2. Being on a path is not the same thing as being in a romance. Each path may also be platonic, based on your choices within it. You do not need to be in a romance to see the path's content. 
				*goto mechmenu
			#What are tone indicators?
				Tone indicators are small icons that may appear in front of some choices. When the option to enable them is switched on, there are certain types of 'tone' that will be designated by such an icon. 
				
				Options with a flirtatious or romantic bent, whether overt or subtle, are indicated with a [♥].
				
				Options that are meant to be humorous rather than serious are marked with a [☆].
				
				Options that have an argumentative, hostile, irritated, grumpy, or similarly negative tone are marked with a [✘].
				
				And lastly, options available to you because of a specific trait you possess, such as options for being particularly-athletic, or drawing on the well of information you might have as a learned character, are indicated with [❋]. 
				
				In general, unmarked options can be read as reasonably serious (thought not necessarily grave), not meant in a hostile manner, and no indication of romantic interest of any kind. 
				*goto mechmenu
			#What is the 'NPC Initiative' feature?
				The NPC initiative feature is an option you, the player, have about how the romanceable NPCs in this game behave. Specifically, whether or not they will ever 'initiate' anything like flirting, romantic gestures or overtures, and the like.
				
				If NPC Initiative is turned OFF, for example, characters will not flirt with you unless you have shown interest by picking an option that indicates that. This is an option you might choose if rejecting characters makes you uncomfortable, of if you don't like to be approached in this way by characters incompatible with the PC.
				
				If NPC Initiative is turned ON, characters will (in ways keeping with their own personalities) take romantic initiative at times, perhaps even if the PC has never directly indicated an interest in them. This is an option you might choose if you like to feel that the relationship you develop is more symmetrical, or if you want the PC to be pursued by their companion. 
				
				Of course, the personality of the characters is the most important thing in either case, so expect any differences between modes to respect that above all else. NPC Initiative does not turn everyone into a flirt, and turning it off won't make everyone completely passive, either, especially if you've already indicated interest. 
				
				Whatever you do, it's recommended you set the option at the beginning of the game and then leave it, as doing otherwise may cause continuity errors, such as the game referring to a previous event that didn't actually happen.
				*goto mechmenu
			#How do traits work?
				Traits are a representation of your character's major strengths and weaknesses. In character creation, you are asked to choose two traits and one drawback (which is like a trait, but with a negative component—a weakness of the character). Drawbacks, though, also grant smaller, more specific strengths. For example, a character who is clumsy and weak for a demigod has learned specific techniques for taking pain and damage. The benefits granted by drawbacks will not be relevant as often as a full strength of the character, but they may have a part to play occasionally.
				
				In general, traits flavor the PC's interactions with the world. Learned PCs may recognize pieces of information, learn things faster, have additional context in some scenarios, and so on. They also provide additional choices in some situations that people without that trait don't have. In general, a trait choice in a situation represents a unique approach possible only for people who have that trait. Whether you choose that option is entirely up to you—traits are not mandatory to good outcomes, and no set of traits is better than another. But they may provide something unique, or good roleplaying opportunities.
				
				Likewise, drawbacks will sometimes present unique challenges or situations for the PC to overcome, or make some things more difficult to do. Just like traits, though, drawbacks are meant as roleplaying elements, things for your PC to compensate for and work with, not gates that 'lock off' potential outcomes. 
				
				Some pieces of text or choices may require a combination of traits and drawbacks.
				*goto mechmenu
			#Is the game tracking my PC's personality?
				It is, yes. These mechanics are hidden because they don't ever determine 'success' or 'failure' at anything, and so you're encouraged to just play a character without worrying about whether a bar is filled enough. Other characters will react to your personality in a way that should feel organic and responsive, but you don't need to have a certain number of points in anything to initiate a romance or accomplish a task.
				
				The PC's personality is just that: how they act in various situations, and how others respond to them in turn. Feel free to experiment with different types of PC and see what changes!
				*goto mechmenu
			#I want to go back to the stats page.
				*goto stats_page
	#Back to stats page
		*goto stats_page

